#include "FS.h"
#include "SD.h"
#include "SPI.h"

void readFile(fs::FS &fs, const char * path){ //imported from arduino SD example: reads the contents of selected File
    Serial.printf("Reading file: %s\n", path);

    File file = fs.open(path);
    if(!file){
        Serial.println("Failed to open file for reading");
        return;
    }

    Serial.print("Read from file: ");
    while(file.available()){
        Serial.write(file.read());
    }
    file.close();
}

void writeFile(fs::FS &fs, const char * path, const char * message){ //imported from arduino SD example: overwrites/creates file and prints data to it
    Serial.printf("Writing file: %s\n", path);

    File file = fs.open(path, FILE_WRITE);
    if(!file){
        Serial.println("Failed to open file for writing");
        return;
    }
    if(file.print(message)){
        Serial.println("File written");
    } else {
        Serial.println("Write failed");
    }
    file.close();
}

void appendFile(fs::FS &fs, const char * path, const char* message){ //imported from arduino SD example: appends data to the end of selected File
    Serial.printf("Appending to file: %s\n", path);

    File file = fs.open(path, FILE_APPEND);
    if(!file){
        Serial.println("Failed to open file for appending");
        return;
    }
    if(file.print(message)){
        Serial.println("Message appended");
    } else {
        Serial.println("Append failed");
    }
    file.close();
}
//Code above is SD card functions and configuration, code below is for the reading of temperature data.

unsigned long testTimer; // Timer to read the pH probe every second
unsigned long writeTimer; // Timer to write data to SD card every 10 minutes

int timeStamp; // time in minutes since device powered on, used as the header for each piece of data appended to pH.txt
float pH_Value; // pH value calculated from voltage read by sensor
String dataPoint; // string combination of tenMinuteAverage and timeStamp that is printed to the pH.txt
float Voltage; // actual value read from pH probe, used to calculate pH, it is its own value to aid calibration of probe and troubleshooting

float oneSecondData_arr[600]; // stores the pH data taken at one second intervals, length 600 because there are 600 seconds in 10 min
int oneSecondArrayIndex=0; // used to index the oneSecondData array

float tenMinuteData_arr[7056]; // stores the ten minute averages locally on the ESP32 for ease of calculation, length 7056 because thats the number of 10minute intervals before millis() rolls over
int tenMinuteArrayIndex=0; // used to index the tenMinuteData array
float tenMinuteAverage=0; // every 10 minutes average of the last 600 seconds of data

float averageArray(String chosenArray){ //averages the selected array, returns average
  float average=0;
  if(chosenArray.equals("oneSecondData")){
    for(int i=0; i<600; i++){
      average=average+oneSecondData_arr[i];
    }
    average=average/600;
  }
  if(chosenArray.equals("overall")){
    for(int i=0; i<tenMinuteArrayIndex+1; i++){
      average=average+tenMinuteData_arr[i];
    }
    average=average/(tenMinuteArrayIndex+1);
  }
  return(average);
}
void commands(String Input){ //used to manage user inputs, moved to function to simplify void loop()
  if(Input=="summary"){
    readFile(SD, "/pH.txt");
  }
  else if(Input=="high/low"){
    float high=0;
    float low=100;
    for(int i=0; i<tenMinuteArrayIndex+1; i++){
      if(tenMinuteData_arr[i]>high){
        high=tenMinuteData_arr[i];
      }
      if(tenMinuteData_arr[i]<low){
        low=tenMinuteData_arr[i];
      }
    }
    Serial.println("The highest recorded average is:");
    Serial.println(high);
    Serial.println("The lowest recorded average is:");
    Serial.println(low);
  }
  else if(Input=="average"){
    Serial.println("The average pH since the device was turned on is:");
    Serial.println(averageArray("overall"));
  }
  else if(Input=="help"){
    Serial.println("Enter \"high/low\" to see the highest and lowest pH values since the device was turned on.");
    Serial.println("Enter \"summary\" to print the contents of pH.txt");
    Serial.println("Enter \"average\" to see the overall pH since the device was turned on");
    Serial.println("Enter \"help\" to see these prompts again");
  }
  else{
    Serial.println("Unrecognized input");
    Serial.println("Enter one of the following valid commands: \"high/low\", \"summary\", \"average\", \"help\"");
    Serial.println("Ensure that the serial port is set to \"no line ending\"");
  }
 
}


void setup(){
    delay(3000); //gives user time to open serial port and see SD status
    Serial.begin(115200);
    if(!SD.begin()){
        Serial.println("Card Mount Failed");
        return;
    }
    uint8_t cardType = SD.cardType();

    if(cardType == CARD_NONE){
        Serial.println("No SD card attached");
        return;
    }

    
    writeFile(SD, "/pH.txt", "Time(min)_pH \n"); //creates pH.txt and gives the data a header
    pinMode(35, INPUT); //pH probe pin
}

void loop(){
  if(millis()>(testTimer+1000)){
    Voltage = analogRead(35) * (3.3 / 4096);
    pH_Value=-5.70*Voltage+21.34;
    oneSecondData_arr[oneSecondArrayIndex]=pH_Value;
    oneSecondArrayIndex++;
    Serial.println(pH_Value);
    testTimer=millis();
  }
  if(millis()>(writeTimer+600000)){
    Serial.println("Appending the following 10 Minute pH average to pH.txt");
    tenMinuteAverage=averageArray("oneSecondData");
    Serial.println(tenMinuteAverage);
    timeStamp=millis()/60000;
    dataPoint=String(timeStamp)+"_"+String(tenMinuteAverage)+"\r\n";
    appendFile(SD, "/pH.txt", dataPoint.c_str());
    tenMinuteData_arr[tenMinuteArrayIndex]=tenMinuteAverage;
    tenMinuteArrayIndex++;
    tenMinuteAverage=0;
    oneSecondArrayIndex=0;
    writeTimer=millis();
  }
  if(Serial.available()>0){
    commands(Serial.readString());
  }
  
  
 

}